正点财经首页     加入收藏
指标首页 通达信指标 同花顺指标 大智慧指标 飞狐指标 指标教程 指标实战 指标百科 股市学院
指标源码搜索: 热词:买卖  黑马  K线  牛股  量能  波段  顶底  抄底  成本  逃顶  MACD  涨停  换手率
你的位置: > 正点财经 > 炒股指标公式 > 通达信指标公式 > 正文

通达信均衡布林BOLL主图指标公式

通达信指标公式源码概况:
  • 指标类别: 通达信指标公式
  • 授权方式: 免费版
  • 指标评级: ★★★★★
  • 指标分类: 趋势
  • 画线方法: 主图
  • 日期:2021-12-24 来源:互联网
通达信指标公式源码介绍:

通达信均衡布林BOLL主图指标公式:

N:=6;K:=12;P:=24;
BG:=BARSCOUNT(C)+2;
NB:=IF(BG<N,BG,N);
KB:=IF(BG<K,BG,K);
PB:=IF(BG<P,BG,P);
MN:=SUM(C,NB)/SUM(1,NB);
MN2:=SUM(C*C,NB)/SUM(1,NB);
MK:=SUM(C,KB)/SUM(1,KB);
MK2:=SUM(C*C,KB)/SUM(1,KB);
MP:=SUM(C,PB)/SUM(1,PB);
MP2:=SUM(C*C,PB)/SUM(1,PB);
MA_S:=POW(MN*MK*MP,1/3);
XZN:=NB/(NB-1);
XZK:=KB/(KB-1);
XZP:=PB/(PB-1);
SD1:=(MN2-MN*MN)*XZN;
SD2:=(MK2-MK*MK)*XZK;
SD3:=(MP2-MP*MP)*XZP;
SD:=SQRT((SD1+SD2+SD3)/3);
顶线:MA_S+2*SD;
强线:MA_S+SD;
中线:MA_S;
弱线:MA_S-SD;
底线:MA_S-2*SD;

通达信均衡布林BOLL主图指标公式实例图解:

通达信均衡布林BOLL主图指标公式

通达信均衡布林BOLL主图指标公式

正点财网所有股票指标公式及文章来源于互联网仅供参考学习,请勿以此为依据进行股票交易,后果自负。

赞助商链接
关于我们 | 商务合作 | 联系投稿 | 联系删稿 | 合作伙伴 | 法律声明 | 网站地图
正点网财经声明︰所载资讯仅代表作者个人观点。不保证该信息(包括但不限于文字、数据及图片)全部或者部分内容的准确性、真实性、完整性、及时性、原创性等,若有侵权,请第一时间告知删除。内容仅供投资者参考,并不构成投资建议,投资者据此操作,风险自担。